Usar o Excel VBA para executar a pesquisa SQL
Sou novo na SQL e na VBA. Eu escrevi uma consulta SQL que eu gostaria de ser capaz de chamar e executar a partir de um sub VBA em um livro de trabalho do excel e, em seguida, trazer os resultados da consulta para o livro de trabalho. Eu encontrei alguns subs on-line (stackoverflow e outros lugares) que afirmam fazer isso, mas eu estou tendo dificuldade em entendê-los, pois eles não contêm nenhuma explicação. Por exemplo, aqui está um sub que eu encontrei online:
Sub ConnectSqlServer()
Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim sConnString As String
' Create the connection string.
sConnString = "Provider=SQLOLEDB;Data Source=INSTANCE\SQLEXPRESS;" & _
"Initial Catalog=MyDatabaseName;" & _
"Integrated Security=SSPI;"
' Create the Connection and Recordset objects.
Set conn = New ADODB.Connection
Set rs = New ADODB.Recordset
' Open the connection and execute.
conn.Open sConnString
Set rs = conn.Execute("SELECT * FROM Table1;")
' Check we have data.
If Not rs.EOF Then
' Transfer result.
Sheets(1).Range("A1").CopyFromRecordset rs
' Close the recordset
rs.Close
Else
MsgBox "Error: No records returned.", vbCritical
End If
' Clean up
If CBool(conn.State And adStateOpen) Then conn.Close
Set conn = Nothing
Set rs = Nothing
End Sub
Em primeiro lugar, isto funcionaria? Segundo, o que preciso substituir no sub (parece provedor, fonte de dados, catálogo inicial, etc) e Onde posso encontrar a informação para substituí-los?
Espero que esta pergunta não seja muito confusa e agradeço a sua ajuda!
33
1 answers
Abaixo está o código que utilizo actualmente para extrair dados de um servidor de MS SQL 2008 para VBA. Você precisa ter a certeza de que tem a referência adequada do ADODB [} Editor de VBA - > Ferramentas - >Referências ] e certifique-se de que tem a biblioteca de dados ActiveX 2.8 da Microsoft ActiveX verificada, que é a segunda a partir da linha inferior que está assinalada (estou a usar o Excel 2010 no Windows 7; poderá ter uma versão ActiveX ligeiramente diferente, mas ainda assim irá começar com a Microsoft ActiveX):
Submódulo para ligar ao MS SQL com máquina remota & utilizador/Senha
Sub Download_Standard_BOM()
'Initializes variables
Dim cnn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim ConnectionString As String
Dim StrQuery As String
'Setup the connection string for accessing MS SQL database
'Make sure to change:
'1: PASSWORD
'2: USERNAME
'3: REMOTE_IP_ADDRESS
'4: DATABASE
ConnectionString = "Provider=SQLOLEDB.1;Password=PASSWORD;Persist Security Info=True;User ID=USERNAME;Data Source=REMOTE_IP_ADDRESS;Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False;Initial Catalog=DATABASE"
'Opens connection to the database
cnn.Open ConnectionString
'Timeout error in seconds for executing the entire query; this will run for 15 minutes before VBA timesout, but your database might timeout before this value
cnn.CommandTimeout = 900
'This is your actual MS SQL query that you need to run; you should check this query first using a more robust SQL editor (such as HeidiSQL) to ensure your query is valid
StrQuery = "SELECT TOP 10 * FROM tbl_table"
'Performs the actual query
rst.Open StrQuery, cnn
'Dumps all the results from the StrQuery into cell A2 of the first sheet in the active workbook
Sheets(1).Range("A2").CopyFromRecordset rst
End Sub
38
Author: Michael, 2016-12-19 22:05:22