Gerar um texto Aleatório e único xslt
Como posso gerar um texto único e aleatório com o xslt para o associar a um atributo de uma marca. por exemplo, quero adicionar um id único a esta marca
<generalization xmi:id="unique ID">
2
2 answers
Pode usar generate-id()
para criar identificadores únicos. Para citar o padrão , " Esta função devolve uma cadeia que identifica um nó dado de forma única."
Considere esta 'stylesheet':
<?xml version='1.0'?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- Replace <xyzzy> with <generalization xml:id="unique ID"> -->
<xsl:template match="xyzzy">
<generalization>
<xsl:apply-templates select="@*"/>
<xsl:attribute name="xml:id"><xsl:value-of select="generate-id()"/></xsl:attribute>
<xsl:apply-templates/>
</generalization>
</xsl:template>
<!-- Copy everything else straight thru -->
<xsl:template match="node( ) | @*">
<xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
</xsl:template>
</xsl:stylesheet>
Aplicado a esta entrada:
<?xml version='1.0' encoding='ASCII'?>
<root>
<xyzzy/>
<xyzzy a="b">
<xyzzy xml:id="non-unique-id"/>
</xyzzy>
</root>
Com este resultado:
<?xml version="1.0"?>
<root>
<generalization xml:id="idp28972496"/>
<generalization a="b" xml:id="idp28945920">
<generalization xml:id="idp28946416"/>
</generalization>
</root>
Observe como o valor de generate-id() é único em todo o documento.
0
Author: Robᵩ, 2015-05-12 22:10:51
Você pode usar o generate-id () com um nó XML temporário para criar cadeias aleatórias de qualquer comprimento:
<!-- language: lang-xml -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:kh="https://github.com/kohsah"
exclude-result-prefixes="xs xd"
version="2.0">
<xsl:function name="kh:shortRandom">
<xsl:variable name="mxml">
<node/>
</xsl:variable>
<xsl:sequence select="generate-id($mxml//node)"/>
</xsl:function>
<xsl:function name="kh:longRandom">
<xsl:sequence select="concat(kh:shortRandom(), kh:shortRandom(), kh:shortRandom(), kh:shortRandom())"></xsl:sequence>
</xsl:function>
<xsl:template match="/">
<test>
<randomId><xsl:value-of select="kh:shortRandom()"/></randomId>
<guid><xsl:value-of select="kh:longRandom()"/></guid>
</test>
</xsl:template>
</xsl:stylesheet>
Existem duas funções XSL aqui:
-
kh:shortRandom()
que gera cadeias aleatórias de 4 letras curtas como esta:"d2e1" -
kh:longRandom()
que gera mais 16 Letras de cadeias aleatórias como esta:"d3e1d4e1d5e1d6e1"
0
Author: kohsah, 2017-04-20 13:40:16